QuickSteps Week, Part 4

Welcome to QuickSteps Week! This week we'll be going over a new Outlook 2010 feature called QuickSteps and how we can simulate some of these features in Outlook 2003 using VBA.

Read previous QuickStep posts:

• QuickSteps Week, Part 1 – Move To Folder
• QuickSteps Week, Part 2 – Forward To Manager
• QuickSteps Week, Part 3 – Done

Each day we'll be going over a different built-in QuickStep, including how to add it to your Standard toolbar. Today we'll go over the Reply & Delete QuickStep.

Opens a reply to the selected message, and then deletes the original message.

This one is another simple QuickStep. Just reply to the currently selected or open item, then delete the original. Note that the original is deleted even if you cancel the reply (the macro isn't smart enough to figure that out).

Sub ReplyAndDelete()

  On Error GoTo ErrorHandler

  Dim currentObject As Object
  Dim msg As Outlook.MailItem
  Dim newMessage As Outlook.MailItem

  ' grab the currently selected or open item
  Set currentObject = GetCurrentItem

  ' act on mailitems only
  If TypeName(currentObject) <> "MailItem" Then
    MsgBox "This code works on e-mail messages only.", vbInformation
    GoTo ProgramExit
  Else
    Set msg = currentObject
  End If

  ' create reply and display for editing
  Set newMessage = msg.Reply
  newMessage.Display

  ' delete original
  With msg
    .UnRead = False
    .Delete
  End With

ProgramExit:
  Exit Sub
ErrorHandler:
  MsgBox Err.Number & " - " & Err.Description
  Resume ProgramExit
End Sub

Add To Toolbar

Taken from Create Outlook toolbar buttons using VBA. This will assign the above macro to a toolbar button on the Standard toolbar.

Sub AddReplyAndDeleteButton()
Call AddToolbarButton("Reply and Delete", "Reply to selected e-mail and delete original", _
                        "ReplyAndDelete", , 328, msoButtonIconAndCaption)
End Sub

Visit Utility Functions for use with Outlook 2003 VBA for a copy of the GetCurrentItem procedure.